Add basic test

Author: natefaubion

bower.json

@@ -23,6 +23,7 @@
     "purescript-psci-support": "^4.0.0",
     "purescript-console": "^4.1.0",
     "purescript-effect": "^2.0.0",
-    "purescript-assert": "^4.0.0"
+    "purescript-assert": "^4.0.0",
+    "purescript-quickcheck": "^5.0.0"
   }
 }

src/Routing/Duplex/Printer.purs

@@ -47,10 +47,11 @@ run = printPath <<< applyFlipped emptyRouteState <<< unwrap
 
 printPath :: RouteState -> String
 printPath { segments, params, hash: hash' } =
-  joinWith "/" segments <> printParams params <> printHash hash'
+  printSegments segments <> printParams params <> printHash hash'
   where
-  printSegments =
-    joinWith "/" <<< map unsafeEncodeURIComponent
+  printSegments = case _ of
+    [""] -> "/"
+    xs -> joinWith "/" $ map unsafeEncodeURIComponent xs
 
   printParams [] = ""
   printParams ps = "?" <> joinWith "&" (uncurry printParam <$> ps)

test/Main.purs

@@ -0,0 +1,78 @@
+module Test.Main where
+
+import Prelude hiding ((/))
+
+import Data.Either (Either(..))
+import Data.Generic.Rep (class Generic)
+import Data.Generic.Rep.Show (genericShow)
+import Data.String.Gen (genAlphaString)
+import Data.Symbol (SProxy(..))
+import Effect (Effect)
+import Routing.Duplex (RouteDuplex', flag, int, param, parse, print, record, rest, root, segment, string, (:=))
+import Routing.Duplex.Generic (noArgs)
+import Routing.Duplex.Generic as RDG
+import Routing.Duplex.Generic.Syntax ((/), (?))
+import Test.QuickCheck (Result(..), arbitrary, quickCheckGen, (===))
+import Test.QuickCheck.Gen (Gen, arrayOf, chooseInt)
+
+data TestRoute
+  = Root
+  | Foo String Int String { a :: String, b :: Boolean }
+  | Bar { id :: String, search :: String }
+  | Baz String (Array String)
+
+derive instance eqTestRoute :: Eq TestRoute
+derive instance genericTestRoute :: Generic TestRoute _
+instance showTestRoute :: Show TestRoute where show = genericShow
+
+genTestRoute :: Gen TestRoute
+genTestRoute = do
+  chooseInt 1 4 >>= case _ of
+    1 -> pure Root
+    2 ->
+      Foo
+        <$> genAlphaString
+        <*> arbitrary
+        <*> genAlphaString
+        <*> ({ a: _, b: _ } <$> genAlphaString <*> arbitrary)
+    3 -> Bar <$> ({ id: _, search: _ } <$> genAlphaString <*> genAlphaString)
+    _ -> Baz <$> genAlphaString <*> (arrayOf genAlphaString)
+
+_id = SProxy :: SProxy "id"
+_search = SProxy :: SProxy "search"
+
+route :: RouteDuplex' TestRoute
+route =
+  root $ RDG.sum
+    { "Root": noArgs
+    , "Foo": fooRoute
+    , "Bar": barRoute
+    , "Baz": bazRoute
+    }
+  where
+  fooRoute =
+    segment / int segment / segment ? { a: string, b: flag }
+
+  barRoute =
+    record
+      # _id := segment
+      # _search := param "search"
+
+  bazRoute =
+    segment / rest
+
+main :: Effect Unit
+main = do
+  quickCheckGen do
+    r <- genTestRoute
+    let
+      url = print route r
+      res = parse route url
+    pure $ case res of
+      Left err ->
+        Failed $
+          show err <> ":"
+            <> "\n  " <> show r
+            <> "\n  " <> show url
+      Right r' ->
+        r === r'